Привет, ребята, у меня есть сервер WSUS, и он отлично работает с активным каталогом. но как я могу подключить компьютеры рабочей группы, работающие на Windows XP, к WSUS, не присоединяя их к AD? Заранее спасибо.
Вы можете внести те же изменения, которые требуются, обновив реестр напрямую; быстрый поиск привел меня к этому ссылка на сайт который, похоже, содержит правильную информацию. Если нет, то чуть более тщательный поиск с вашей стороны, скорее всего, поможет вам получить недостающую информацию.
Я использую следующий пакетный сценарий для включения и выключения систем WSUS. Он отлично работает, чтобы быстро обновить отформатированные системы, прежде чем мы их отдадим.
Измените [СЕРВЕР] на свой сервер WSUS под :USEWSUS раздел.
@echo off
:START
cls
echo Temporary WSUS Script
echo ==============================
echo This script will flip between using the internal WSUS server and Microsoft's servers.
echo.
set /p WSUSSETTING=Type [W] to use WSUS or [C] to clear the setting and use MS servers:
IF /i (%WSUSSETTING%) == (W) goto CONTINUE
if /i (%WSUSSETTING%) == (C) goto CONTINUE
echo.
echo Error: Invalid selection
pause
goto START
:CONTINUE
echo Stopping Update Services...
net stop wuauserv
echo Deleting timeout registry entries (Safe to ignore errors)...
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v LastWaitTimeout /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v DetectionStartTime /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v NextDetectionTime /f
IF /i (%WSUSSETTING%) == (W) goto USEWSUS
IF /i (%WSUSSETTING%) == (C) goto USEMS
:USEWSUS
echo Changing update server to local WSUS server...
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v NoAutoUpdate /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AUOptions /t REG_DWORD /d 3 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AutoInstallMinorUpdate /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /t REG_DWORD /d 1 /f
goto COMPLETE
:USEMS
echo Clearing WSUS update server...
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /f
goto COMPLETE
:COMPLETE
echo Starting Update Services...
net start wuauserv
:END
echo ---
echo Complete.
pause
Если это Professional Edition, вы также можете использовать локальную групповую политику. Бегать gpedit.msc и перейдите к «Конфигурация компьютера -> Административные шаблоны -> Компоненты Windows -> Центр обновления Windows».