Где я могу скачать описание всех системных служб Windows Server 2008?

Ты ищешь Обзор службы и требования к сетевому порту для системы Windows Server (KB832017).

Также статья о безопасности Windows, Управление безопасностью службы с помощью Windows Server 2008.

Я не уверен, что именно вы ищете, но я думаю, что хорошей отправной точкой является Страница информации о продукте Microsoft Windows Server 2008, особенно Раздел официальных документов и страница функций.

Следующая ссылка, например, ведет к длинному документу на 160 страниц: "Технический обзор Windows Server 2008 (полный документ)".

Дополнительную техническую информацию можно найти на Раздел Windows Server 2008 на TechNet.

Скрипт VB есть на этот сайт технических задач это должно помочь перечислить доступные услуги.

' This code prints the list of services on a machine
' ---------------------------------------------------------------
' From the book "Windows Server Cookbook" by Robbie Allen
' ISBN: 0-596-00633-0
' ---------------------------------------------------------------

' ------ SCRIPT CONFIGURATION ------
strComputer = "<ServerName>"  ' e.g. fs-rtp01 (use . for local server)
boolShowDetails = TRUE        ' set to FALSE to display list w/o details
' ------ END CONFIGURATION ---------
set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
set objServices = objWMI.InstancesOf("Win32_Service")

for each objService in objServices
   WScript.Echo objService.Name
   if boolShowDetails = TRUE then
      for each objProp in objService.Properties_
         ' Print out NULL if the property is blank
         if IsNull(objProp.Value) then
            Wscript.Echo " " & objProp.Name & " : NULL"
         else
         ' If the value is an array, we need to iterate through each element
         ' of the array
            if objProp.IsArray = TRUE then
               For I = LBound(objProp.Value) to UBound(objProp.Value)
                  wscript.echo " " & objProp.Name & " : " & objProp.Value(I)
               next
            else
           ' If the property was  not NULL or an array, we print it
                wscript.echo " " & objProp.Name & " : " & objProp.Value
            end if
         end if
      next
      WScript.Echo ""
   end if
next