Как разбить и отформатировать несколько дисков с помощью пакетного сценария?

Я пытаюсь отформатировать n дисков с помощью пакетного сценария. Мой сценарий выглядит так.

diskpart /s "abc.txt"

где abc.txt:

sel disk 1
create part primary
format FS=NTFS  label=label2 quick compress

Моя проблема здесь в том, что я хочу «зациклить» команды в abc.txt для количества существующих дисков. Но я не могу отправить аргумент типа% 1 в файл abc.txt, так как это файл .txt. и мой diskpart / s может принимать только файл .txt в качестве аргумента. как преодолеть это ... может кто-нибудь помочь?

windows batch-file

Следующее может сработать, вроде:

echo list disk > list.txt
for /f "usebackq tokens=1,2" %%a in (`diskpart /s list.txt ^| findstr /r /c:"Disk [0-9]"`) do (
   echo sel %%a %%b>abc.txt
   echo create part primary>>abc.txt
   echo format FS=NTFS  label=label2 quick compress>>abc.txt
   diskpart /s abc.txt
)
del list.txt abc.txt

Сначала он получит список дисков от diskpart и впоследствии будет использовать их с вашим файлом сценария (который будет динамически создан в цикле).

Я не буду здесь пробовать, так как мне нравятся мои диски такими, какие они есть сейчас.

@echo off
setlocal enabledelayedexpansion
cls
:: Eg. To enable choice prompt, change to set _CHOICE.ENABLE=
::     To disable choice prompt, change to set _CHOICE.ENABLE=::
::     Do the same for set _DISKPART.ENABLE=::
set _CHOICE.ENABLE=
set _DISKPART.ENABLE=::

set _TMP.FILE=%~dp0%~n0.DPS

for /f "skip=1 tokens=1" %%a in ('wmic diskdrive where "MediaType='Fixed Hard Disk Media'" get index') do (set _DISK.AVAIL=!_DISK.AVAIL! %%a)
set _DISK.AVAIL=!_DISK.AVAIL:~1!

for %%a in (!_DISK.AVAIL!) do (set "_DISKPART.SCRIPT=!_DISKPART.SCRIPT!select-disk-%%a create-partition-primary format-fs=ntfs-label="LABEL%%a"-quick-compress ")

:_FN.VAR2FILE
for /f "tokens=1*" %%a in ("!_DISKPART.SCRIPT!") do (
   set _DISKPART.SCRIPT.FORMAT=%%a
   set _DISKPART.SCRIPT.FORMAT=!_DISKPART.SCRIPT.FORMAT:-= !
   if not exist "%_TMP.FILE%" (echo !_DISKPART.SCRIPT.FORMAT! > %_TMP.FILE%) else (echo !_DISKPART.SCRIPT.FORMAT! >> %_TMP.FILE%)
   set _DISKPART.SCRIPT=%%b
)
if defined _DISKPART.SCRIPT (goto :_FN.VAR2FILE)

echo Generated Script^:
type %_TMP.FILE% | more
%_CHOICE.ENABLE% CHOICE /C TC /M "[T]erminate, or [C]ontinue"
%_CHOICE.ENABLE% if errorlevel 2 (call :_FN.DISKPART.RUN)
goto :_FN.FINISH
goto :eof

:_FN.DISKPART.RUN
if "!_DISKPART.ENABLE!"=="::" (echo Command is disabled, please see the header for information on how to enable it.)
%_DISKPART.ENABLE% diskpart /s %_TMP.FILE%
goto :eof

:_FN.FINISH
if exist "%_TMP.FILE%" (del /q %_TMP.FILE%)
echo All Done.
goto :eof

Элегантное решение.

Если вы всегда повторяете одни и те же диски, вы можете просто вставить их как статические. Я сделал это для USB-ключей.

SELECT DISK 6
CLEAN
CREATE PART PRI 
SELECT PART 1 
ACTIVE 
ASSIGN
FORMAT FS=fat32 quick label="WINPE"

SELECT DISK 7
CLEAN
CREATE PART PRI 
SELECT PART 1 
ACTIVE 
ASSIGN
FORMAT FS=fat32 quick label="WINPE"
EXIT

Вы можете просто зациклить и автоматически воссоздавать файл «abc.txt» на каждой итерации.