Я пытаюсь создать виртуальный каталог под «Веб-сайтом по умолчанию» в IIS 7, используя AppCmd.
Но сначала я хотел бы увидеть, существует ли он уже. Как я могу использовать AppCmd чтобы создать виртуальный каталог под «Веб-сайтом по умолчанию» и как я могу сделать оператор if?
Попробуй это:
@ECHO OFF
REM --------------------------------------------------------------------------------
REM Check for and create VDir under Default Web Site
REM
REM %1 is the VDIR to create
REM %2 is the Physical path to the VDIR
REM --------------------------------------------------------------------------------
IF "%1"=="" GOTO Syntax
IF "%2"=="" GOTO Syntax
ECHO Running...
ECHO AppCmd.exe list vdir "Default Web Site/%1/"
ECHO.
AppCmd.exe list vdir "Default Web Site/%1/"
IF %errorlevel%==1 GOTO Exists
ECHO.
ECHO Running...
ECHO AppCmd.exe ADD vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2
ECHO.
AppCmd.exe ADD vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2
GOTO End
:Exists
ECHO.
ECHO VDir already exists
ECHO.
GOTO End
:SYNTAX
ECHO.
ECHO VDir Name and Physical Path Required
ECHO.
ECHO CreateVDir.CMD ^<VDirName^> C:\PhysPath
ECHO.
:END
Попробуй это. В основном то же самое, что и ответ, данный Christopher_G_Lewis, но полагается на синтаксический анализ вывода списка вместо кода ошибки, которого я тоже не получаю.
Также используется конструкция оболочки cmd.exe A || B (если A терпит неудачу, сделайте B)
@ECHO OFF
REM --------------------------------------------------------------------------------
REM Check for and create VDir under Default Web Site
REM
REM %1 is the VDIR to create
REM %2 is the Physical path to the VDIR
REM --------------------------------------------------------------------------------
IF "%1"=="" GOTO Syntax
IF "%2"=="" GOTO Syntax
AppCmd.exe list vdir "Default Web Site/%1/" | findstr /I "Default Web Site/%1/" || AppCmd.exe add vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2
goto :eof